//
// CPT operator / SondeerGame 
// This source file is (c) by Deltares.
// - October 2014
//

/// jln - 05-08-2008 
/// Simple class that inherits GUIPage and extends with some extras
/// all our own pages should inherit fomr GeoGUIPage now!!

class GeoGUIPage extends GUIPage;

var GeoPlayerController GeoPC;

var bool AllowSelect;                        // To make sure that on sub menus appear can't click on parent menu's components

/// jln - 16-09-2008 Scenariofile name for the int file, to make sure we get our data from the proper file.
var string ScenarioFile;

/// jln - 05-08-2008 Init component and language.
function InitComponent(GUIController MyController, GUIComponent MyOwner)
{
    Super.InitComponent(MyController, MyOwner);

	if(GeoPC == none)
	{
		GeoPC = GeoPlayerController(PlayerOwner());
	}

	GeoPC.BrakeVehicle();

	InitLanguages();
}

event Closed(GUIComponent Sender, bool bCancelled)
{
	Super.Closed(Sender, bCancelled);
    OnClose(bCancelled);

	/// Reset brake values:
	GeoPC.ResetBrake();
}



function InitLanguages(optional string lang)
{
	local int i;
	local string Language;


	if (Len(lang) > 0)
	{
		Language = "Language_" $ lang;		
	} else {
		Language = "Language_" $ GeoPC.PlayerLanguage;

	}

	/// Set scenario file:
	ScenarioFile = "scenario" $ GeoPC.GetScenarioNumber();


	Log("This is window class: " @ self.Class);
	Log("Using language: " @ Language);

	for (i = 0; i < Controls.Length; i++)
	{
		/// Ini option available?
		if (Len(Controls[i].IniOption) > 0)
		{
			if (Controls[i].IniOption != "@INTERNAL")
			{

				if (Controls[i].IsA('GUILabel'))
				{
					GUILabel(Controls[i]).Caption = Localize(String(self.Class), Controls[i].IniOption , Language);
				}

				if (Controls[i].IsA('GUIButton'))
				{
					GUIButton(Controls[i]).Caption = Localize(String(self.Class), Controls[i].IniOption , Language);
				}


				if (Controls[i].IsA('moCheckBox'))
				{
					moCheckBox(Controls[i]).MyLabel.Caption = Localize(String(self.Class), Controls[i].IniOption , Language);
				}
			}
		}
	}
}

/// jln - 08-08-2008  Internationalize an item (IL8N);
function string IL8N(string item)
{
	local string Language;

	Language = "Language_" $ GeoPC.GetLanguage();
	return Localize(String(self.Class), item , Language);
}

//=============================================================================
// Date       Id   Modification
// 2006-11-17 The  Created this header
//=============================================================================
function ChangeAllow(bool a)
{
    AllowSelect = a;
}