//
// CPT operator / SondeerGame 
// This source file is (c) by Deltares.
// - October 2014
//
//=============================================================================
// Date       Id   Modification
//
// 12-08-2008 Wsl  Copied from MenuCheckList, new interface design
//=============================================================================
class MenuOpdrachtBon extends GeoGUIPage;

#exec OBJ LOAD FILE=GeoGUIContent.utx

var bool bIgnoreEsc;

var float VGapSmall;
var float VGapMedium;
var float VGapLarge;
var float HGap;
var float DialogGap;

var GeoPlayerController GeoPC;

var automated GeoImage	PaperBackground;
var automated GeoFrame 	DialogBackground;

// opdrachtbon itself
var automated GeoLabel OpdrachtbonLabel;

var automated GeoLabel CategorieOpdrachtLabel;
var automated GeoMultiLineLabelSmall OpdrachtText;

var automated GeoLabel CategorieAlgemeenLabel;
var automated GeoLabel TitelLabel;
var automated GeoLabel DatumLabel;
var automated GeoLabel LocatieLabel;
var automated GeoLabel OpdrachtgeverLabel;

var automated GeoLabel CategorieVeiligheidLabel;
var automated GeoLabel VerontreinigdeGrondLabel;
var automated GeoLabel VGPlanLabel;
var automated GeoLabel SpoorveiligheidLabel;
var automated GeoLabel VerkeersafzettingenLabel;
var automated GeoLabel WaterwerkLabel;
var automated GeoLabel KLICLabel;
var automated GeoLabel VCALabel;
var automated GeoLabel BRLLabel;
var automated GeoLabel WerkbriefLabel;
var automated GeoImage VerontreinigdeGrondCheck;
var automated GeoImage VGPlanCheck;
var automated GeoImage SpoorveiligheidCheck;
var automated GeoImage VerkeersafzettingenCheck;
var automated GeoImage WaterwerkCheck;
var automated GeoImage KLICCheck;
var automated GeoImage VCACheck;
var automated GeoImage BRLCheck;
var automated GeoImage WerkbriefCheck;
var automated GeoButtonSmall MapButton;
var automated GeoButtonSmall KLICButton;

var automated GeoLabel CategorieVoorbereidingLabel;
var automated GeoLabel ToestemmingLabel;
var automated GeoLabel UitzettenLabel;
var automated GeoLabel InmetenLabel;
var automated GeoLabel WaterpassenLabel;
var automated GeoLabel ToestemmingPartijLabel;
var automated GeoLabel UitzettenPartijLabel;
var automated GeoLabel InmetenPartijLabel;
var automated GeoLabel WaterpassenPartijLabel;

// checklist
var automated GeoLabel ControleLijstLabel;

var automated GeoLabel OpdrachtControleLabel;
var automated GeoLabel AlgemeenControleLabel;
var automated GeoLabel VeiligheidControleLabel;
var automated GeoLabel VoorbereidingControleLabel;

var automated GeoLabel JuistLabel;
var automated GeoLabel OnjuistLabel;

var automated GeoMultiLineLabel UitlegText;

var automated GeoButton OpdrachtbonGoedButton;

var automated GeoApprovalCheck GeoApprovalCheckOpdracht;
var automated GeoApprovalCheck GeoApprovalCheckAlgemeen;
var automated GeoApprovalCheck GeoApprovalCheckVeiligheid;
var automated GeoApprovalCheck GeoApprovalCheckVoorbereiding;

function InitComponent(GUIController MyController, GUIComponent MyOwner)
{
	local float OpdrachtBonLeft, OpdrachtBonRight, OpdrachtBonTop, OpdrachtBonBottom;
	local float ControleLijstLeft, ControleLijstRight, ControleLijstTop, ControleLijstBottom;

	Super.InitComponent(MyController, MyOwner);

	GeoPC = GeoPlayerController(PlayerOwner());

	OpdrachtBonLeft = PaperBackground.WinLeft + DialogGap;
	OpdrachtBonRight = PaperBackground.WinLeft + PaperBackground.WinWidth - DialogGap;
	OpdrachtBonTop = PaperBackground.WinTop + DialogGap;
	OpdrachtBonBottom = PaperBackground.WinTop + PaperBackground.WinHeight - DialogGap;

    ControleLijstLeft = DialogBackground.WinLeft + (DialogGap / 4) * 3;
	ControleLijstRight = DialogBackground.WinLeft + DialogBackground.WinWidth - DialogGap;
	ControleLijstTop = DialogBackground.WinTop + DialogGap;
	ControleLijstBottom = DialogBackground.WinTop + DialogBackground.WinHeight - DialogGap;

	OpdrachtBonLabel.WinLeft = OpdrachtBonLeft;
	OpdrachtBonLabel.WinTop = OpdrachtBonTop;

	// assignment category multiline label
	CategorieOpdrachtLabel.WinLeft = OpdrachtBonLeft;
	CategorieOpdrachtLabel.WinTop = OpdrachtBonLabel.WinTop + OpdrachtBonLabel.WinHeight + VGapMedium;

    OpdrachtText.WinLeft = OpdrachtBonLeft;
    OpdrachtText.WinWidth = OpdrachtBonRight - OpdrachtBonLeft;
    OpdrachtText.WinTop = CategorieOpdrachtLabel.WinTop + CategorieOpdrachtLabel.WinHeight + VGapSmall;
	OpdrachtText.BlackText(true);

	// general information category
	CategorieAlgemeenLabel.WinLeft = OpdrachtBonLeft;
	CategorieAlgemeenLabel.WinTop = OpdrachtText.WinTop + OpdrachtText.WinHeight + VGapSmall;

    TitelLabel.WinLeft = OpdrachtBonLeft;
    TitelLabel.WinTop = CategorieAlgemeenLabel.WinTop + CategorieAlgemeenLabel.WinHeight + VGapSmall;

    DatumLabel.WinLeft = OpdrachtBonLeft;
    DatumLabel.WinTop = TitelLabel.WinTop + TitelLabel.WinHeight + VGapSmall;

    LocatieLabel.WinLeft = OpdrachtBonLeft;
    LocatieLabel.WinTop = DatumLabel.WinTop + DatumLabel.WinHeight + VGapSmall;
    LocatieLabel.WinWidth = (OpdrachtBonRight - OpdrachtBonLeft) / 2.0;

    MapButton.WinLeft = (OpdrachtBonRight - OpdrachtBonLeft) / 2.0 + OpdrachtBonLeft + HGap;
    MapButton.WinTop = LocatieLabel.WinTop - 0.004;
   
	if(GeoPC.GetScenarioNumber() == 1 || GeoPC.GetScenarioNumber() == 4)
	{
		MapButton.SetVisibility(true);
	}
	else
	{
		// in scenario 2, there's no map. For scenario 3, they forget to give you
		// the map so it will become visible after you've corrected your boss.
		MapButton.SetVisibility(false);
	}

    OpdrachtgeverLabel.WinLeft = OpdrachtBonLeft;
    OpdrachtgeverLabel.WinTop = LocatieLabel.WinTop + LocatieLabel.WinHeight + VGapSmall;

	// veiligheid en kwaliteit checkboxes
    CategorieVeiligheidLabel.WinLeft = OpdrachtBonLeft;
	CategorieVeiligheidLabel.WinTop = OpdrachtgeverLabel.WinTop + OpdrachtgeverLabel.WinHeight + VGapMedium;

    VerontreinigdeGrondCheck.WinLeft = OpdrachtBonLeft;
    VerontreinigdeGrondCheck.WinTop = CategorieVeiligheidLabel.WinTop + CategorieVeiligheidLabel.WinHeight + VGapSmall;
    VerontreinigdeGrondLabel.WinLeft = VerontreinigdeGrondCheck.WinLeft + VerontreinigdeGrondCheck.WinWidth + HGap;
    VerontreinigdeGrondLabel.WinTop = VerontreinigdeGrondCheck.WinTop;

    VGPlanCheck.WinLeft = VerontreinigdeGrondCheck.WinLeft;
    VGPlanCheck.WinTop = VerontreinigdeGrondCheck.WinTop + VerontreinigdeGrondCheck.WinHeight + VGapSmall;
    VGPlanLabel.WinLeft = VGPlanCheck.WinLeft + VGPlanCheck.WinWidth + HGap;
    VGPlanLabel.WinTop = VGPlanCheck.WinTop;

    SpoorveiligheidCheck.WinLeft = VerontreinigdeGrondCheck.WinLeft;
    SpoorveiligheidCheck.WinTop = VGPlanCheck.WinTop + VGPlanCheck.WinHeight + VGapSmall;
    SpoorveiligheidLabel.WinLeft = SpoorveiligheidCheck.WinLeft + SpoorveiligheidCheck.WinWidth + HGap;
    SpoorveiligheidLabel.WinTop = SpoorveiligheidCheck.WinTop;

    VerkeersafzettingenCheck.WinLeft = VerontreinigdeGrondCheck.WinLeft;
    VerkeersafzettingenCheck.WinTop = SpoorveiligheidCheck.WinTop + SpoorveiligheidCheck.WinHeight + VGapSmall;
    VerkeersafzettingenLabel.WinLeft = VerkeersafzettingenCheck.WinLeft + VerkeersafzettingenCheck.WinWidth + HGap;
    VerkeersafzettingenLabel.WinTop = VerkeersafzettingenCheck.WinTop;

    WaterwerkCheck.WinLeft = (OpdrachtBonRight - OpdrachtBonLeft) / 2.0 + OpdrachtBonLeft;
    WaterwerkCheck.WinTop = VerontreinigdeGrondCheck.WinTop;
    WaterwerkLabel.WinLeft = WaterwerkCheck.WinLeft + WaterwerkCheck.WinWidth + HGap;
    WaterwerkLabel.WinTop = WaterwerkCheck.WinTop;

    KLICCheck.WinLeft = VerontreinigdeGrondCheck.WinLeft;
    KLICCheck.WinTop = VerkeersafzettingenCheck.WinTop + VerkeersafzettingenCheck.WinHeight + VGapSmall;
    KLICLabel.WinLeft = KLICCheck.WinLeft + KLICCheck.WinWidth + HGap;
    KLICLabel.WinTop = KLICCheck.WinTop;

	KLICButton.WinLeft = WaterwerkCheck.WinLeft; //(OpdrachtBonRight - OpdrachtBonLeft) / 2.0 + OpdrachtBonLeft - KLICButton.WinWidth;
    KLICButton.WinTop = KLICCheck.WinTop - 0.004;
    KLICButton.SetVisibility(false);

    VCACheck.WinLeft = WaterwerkCheck.WinLeft;
    VCACheck.WinTop = WaterwerkCheck.WinTop + WaterwerkCheck.WinHeight + VGapSmall;
    VCALabel.WinLeft = VCACheck.WinLeft + VCACheck.WinWidth + HGap;
    VCALabel.WinTop = VCACheck.WinTop;

    BRLCheck.WinLeft = WaterwerkCheck.WinLeft;
    BRLCheck.WinTop = VCACheck.WinTop + VCACheck.WinHeight + VGapSmall;
    BRLLabel.WinLeft = BRLCheck.WinLeft + BRLCheck.WinWidth + HGap;
    BRLLabel.WinTop = BRLCheck.WinTop;

    WerkbriefCheck.WinLeft = WaterwerkCheck.WinLeft;
    WerkbriefCheck.WinTop = BRLCheck.WinTop + BRLCheck.WinHeight + VGapSmall;
    WerkbriefLabel.WinLeft = WerkbriefCheck.WinLeft + WerkbriefCheck.WinWidth + HGap;
    WerkbriefLabel.WinTop = WerkbriefCheck.WinTop;

    // voorbereiding partijen labels
    CategorieVoorbereidingLabel.WinLeft = OpdrachtBonLeft;
	CategorieVoorbereidingLabel.WinTop = KLICCheck.WinTop + KLICCheck.WinHeight + VGapMedium;

	ToestemmingLabel.WinLeft = OpdrachtBonLeft;
	ToestemmingLabel.WinTop = CategorieVoorbereidingLabel.WinTop + CategorieVoorbereidingLabel.WinHeight + VGapSmall;
    ToestemmingPartijLabel.WinLeft = OpdrachtBonRight - ToestemmingPartijLabel.WinWidth;
    ToestemmingPartijLabel.WinTop = ToestemmingLabel.WinTop;

    UitzettenLabel.WinLeft = OpdrachtBonLeft;
	UitzettenLabel.WinTop = ToestemmingLabel.WinTop + ToestemmingLabel.WinHeight + VGapSmall;
    UitzettenPartijLabel.WinLeft = OpdrachtBonRight - UitzettenPartijLabel.WinWidth;
    UitzettenPartijLabel.WinTop = UitzettenLabel.WinTop;

    InmetenLabel.WinLeft = OpdrachtBonLeft;
	InmetenLabel.WinTop = UitzettenLabel.WinTop + UitzettenLabel.WinHeight + VGapSmall;
    InmetenPartijLabel.WinLeft = OpdrachtBonRight - InmetenPartijLabel.WinWidth;
    InmetenPartijLabel.WinTop = InmetenLabel.WinTop;

    WaterpassenLabel.WinLeft = OpdrachtBonLeft;
	WaterpassenLabel.WinTop = InmetenLabel.WinTop + InmetenLabel.WinHeight + VGapSmall;
    WaterpassenPartijLabel.WinLeft = OpdrachtBonRight - WaterpassenPartijLabel.WinWidth;
    WaterpassenPartijLabel.WinTop = WaterpassenLabel.WinTop;

	// controlelijst checklist part
    ControleLijstLabel.WinLeft = ControleLijstLeft;
	ControleLijstLabel.WinTop = ControleLijstTop + 0.025;

    UitlegText.WinLeft = ControleLijstLeft;
    UitlegText.WinWidth = ControleLijstRight - ControleLijstLeft;
	UitlegText.WinTop = ControleLijstLabel.WinTop + ControleLijstLabel.WinHeight + VGapLarge;

	OpdrachtControleLabel.WinLeft = ControleLijstLeft;
    OpdrachtControleLabel.WinTop = UitlegText.WinTop + UitlegText.WinHeight + VGapSmall;
    GeoApprovalCheckOpdracht.WinLeft = 0.01 + DialogBackground.WinLeft + DialogBackground.WinWidth - DialogGap - (2.0*GeoApprovalCheckOpdracht.WinWidth/3.0);
    GeoApprovalCheckOpdracht.WinTop = OpdrachtControleLabel.WinTop - (1.0*GeoApprovalCheckOpdracht.WinHeight/3.0);

    AlgemeenControleLabel.WinLeft = ControleLijstLeft;
    AlgemeenControleLabel.WinTop = OpdrachtControleLabel.WinTop + OpdrachtControleLabel.WinHeight + VGapMedium;
	GeoApprovalCheckAlgemeen.WinLeft = 0.01 + DialogBackground.WinLeft + DialogBackground.WinWidth - DialogGap - (2.0*GeoApprovalCheckAlgemeen.WinWidth/3.0);
    GeoApprovalCheckAlgemeen.WinTop = AlgemeenControleLabel.WinTop - (1.0*GeoApprovalCheckAlgemeen.WinHeight/3.0);


    VeiligheidControleLabel.WinLeft = ControleLijstLeft;
    VeiligheidControleLabel.WinTop = AlgemeenControleLabel.WinTop + AlgemeenControleLabel.WinHeight + VGapMedium;
	GeoApprovalCheckVeiligheid.WinLeft = 0.01 + DialogBackground.WinLeft + DialogBackground.WinWidth - DialogGap - (2.0*GeoApprovalCheckVeiligheid.WinWidth/3.0);
    GeoApprovalCheckVeiligheid.WinTop = VeiligheidControleLabel.WinTop - (1.0*GeoApprovalCheckVeiligheid.WinHeight/3.0);

    VoorbereidingControleLabel.WinLeft = ControleLijstLeft;
    VoorbereidingControleLabel.WinTop = VeiligheidControleLabel.WinTop + VeiligheidControleLabel.WinHeight + VGapMedium;
	GeoApprovalCheckVoorbereiding.WinLeft = 0.01 + DialogBackground.WinLeft + DialogBackground.WinWidth - DialogGap - (2.0*GeoApprovalCheckVoorbereiding.WinWidth/3.0);
    GeoApprovalCheckVoorbereiding.WinTop = VoorbereidingControleLabel.WinTop - (1.0*GeoApprovalCheckVoorbereiding.WinHeight/3.0);

    OpdrachtbonGoedButton.WinLeft = ControleLijstRight - (OpdrachtbonGoedButton.WinWidth * 1.2);
    OpdrachtbonGoedButton.WinTop = ControleLijstBottom - OpdrachtbonGoedButton.WinHeight;
	
	// to prevent scrollbar from appearing in this text box
	OpdrachtText.WinHeight += 0.1;

	SetCheckBoxes();

	SetCaptions();

	// if the opdrachtbon was already approved, only show opdrachtbon itself
	if(GeoPC.playeractions.ApprovedAssignment)
	{
		HideRightPart();
	}
}

//=============================================================================
// Date       Id   Modification
// 2008-08-12 Wsl  Created this header
//
// Retrieve all the captions for all the labels in the menu depending on language
// settings (each language has an int file), and depending on the scenario that's
// being played (separate int files for each scenario).
//=============================================================================
function SetCaptions()
{
	local string s;

	s = "GeoInterface.MenuOpdrachtBon";

	OpdrachtBonLabel.Caption = GeoPC.IL8N("OpdrachtBon", s, false);
	CategorieOpdrachtLabel.Caption = GeoPC.IL8N("Opdracht", s, false);
	OpdrachtText.SetContent(GeoPC.IL8N("Opdracht", s, true));
	CategorieAlgemeenLabel.Caption = GeoPC.IL8N("Algemeen", s, false);
	TitelLabel.Caption = GeoPC.IL8N("Titel", s, false) @ GeoPC.IL8N("Titel", s, true);
	DatumLabel.Caption = GeoPC.IL8N("Datum", s, false) @ GeoPC.IL8N("Datum", s, true);
	LocatieLabel.Caption = GeoPC.IL8N("Locatie", s, false) @ GeoPC.IL8N("Locatie", s, true);
	MapButton.Caption = GeoPC.IL8N("MapButton", s, false);
	OpdrachtgeverLabel.Caption = GeoPC.IL8N("Opdrachtgever", s, false) @ GeoPC.IL8N("Opdrachtgever", s, true);
    CategorieVeiligheidLabel.Caption = GeoPC.IL8N("Veiligheid", s, false);
	VerontreinigdeGrondLabel.Caption = GeoPC.IL8N("VerontreinigdeGrond", s, false);
    VGPlanLabel.Caption = GeoPC.IL8N("VGPlan", s, false);
    SpoorveiligheidLabel.Caption = GeoPC.IL8N("Spoorveiligheid", s, false);
    VerkeersafzettingenLabel.Caption = GeoPC.IL8N("Verkeersafzettingen", s, false);
    WaterwerkLabel.Caption = GeoPC.IL8N("Waterwerk", s, false);
    KLICLabel.Caption = GeoPC.IL8N("KLIC", s, false);
    VCALabel.Caption = GeoPC.IL8N("VCA", s, false);
    BRLLabel.Caption = GeoPC.IL8N("BRL", s, false);
    WerkbriefLabel.Caption = GeoPC.IL8N("Werkbrief", s, false);
    KLICButton.Caption = GeoPC.IL8N("KLICButton", s, false);
    CategorieVoorbereidingLabel.Caption = GeoPC.IL8N("Voorbereiding", s, false);
    ToestemmingLabel.Caption = GeoPC.IL8N("Toestemming", s, false);
    ToestemmingPartijLabel.Caption = GeoPC.IL8N("ToestemmingPartij", s, true);
    UitzettenLabel.Caption = GeoPC.IL8N("Uitzetten", s, false);
    UitzettenPartijLabel.Caption = GeoPC.IL8N("UitzettenPartij", s, true);
    InmetenLabel.Caption = GeoPC.IL8N("Inmeten", s, false);
    InmetenPartijLabel.Caption = GeoPC.IL8N("InmetenPartij", s, true);
    WaterpassenLabel.Caption = GeoPC.IL8N("Waterpassen", s, false);
    WaterpassenPartijLabel.Caption = GeoPC.IL8N("WaterpassenPartij", s, true);
	ControleLijstLabel.Caption = GeoPC.IL8N("ControleLijst", s, false);
	OpdrachtControleLabel.Caption = GeoPC.IL8N("OpdrachtControle", s, false);
	AlgemeenControleLabel.Caption = GeoPC.IL8N("AlgemeenControle", s, false);
	VeiligheidControleLabel.Caption = GeoPC.IL8N("VeiligheidControle", s, false);
	VoorbereidingControleLabel.Caption = GeoPC.IL8N("VoorbereidingControle", s, false);
	JuistLabel.Caption = GeoPC.IL8N("Juist", s, false);
	OnjuistLabel.Caption = GeoPC.IL8N("Onjuist", s, false);
	UitlegText.SetContent(GeoPC.IL8N("Uitleg", s, false));
	OpdrachtbonGoedButton.Caption = GeoPC.IL8N("OpdrachtbonGoed", s, false);

}

// show only left part, the assignment itself. Called in case the opdrachtbon was already approved.
// changes caption of approve button into 'close' and repositions it.
function HideRightPart()
{
	GeoApprovalCheckOpdracht.SetVisibility(false);
	GeoApprovalCheckAlgemeen.SetVisibility(false);
	GeoApprovalCheckVeiligheid.SetVisibility(false);
	GeoApprovalCheckVoorbereiding.SetVisibility(false);

	ControleLijstLabel.SetVisibility(false);

	OpdrachtControleLabel.SetVisibility(false);
	AlgemeenControleLabel.SetVisibility(false);
	VeiligheidControleLabel.SetVisibility(false);
	VoorbereidingControleLabel.SetVisibility(false);

	JuistLabel.SetVisibility(false);
	OnjuistLabel.SetVisibility(false);

	UitlegText.SetVisibility(false);

	DialogBackground.SetVisibility(false);

	OpdrachtBonGoedButton.Caption = ( GeoPC.IL8N("close", "GeoInterface.MenuOpdrachtBon", false) );
	OpdrachtBonGoedButton.WinTop = 0.1;
	OpdrachtBonGoedButton.WinLeft = 0.34;
	OpdrachtBonGoedButton.WinWidth = 0.1;
}


function bool CheckIsChecked(GeoImage oImage, string strcheck)
{
	local string s;
	s = GeoPC.GetScenarioFile();

	/// checked?
	if (bool(Localize("CheckBoxes", strCheck, s)) == true)
	{
		oImage.Image = Material'GeoGUIContent.Icons.checkbox_marked';

		return true;
	}

	return false;


}

function SetCheckBoxes()
{
	CheckIsChecked(VerontreinigdeGrondCheck, "VerontreinigdeGrondCheck");
	CheckIsChecked(VGPlanCheck, "VGPlanCheck");
	CheckIsChecked(SpoorveiligheidCheck, "SpoorveiligheidCheck");
	CheckIsChecked(VerkeersafzettingenCheck, "VerkeersafzettingenCheck");

	/// KLIC available?
	if (CheckIsChecked(KLICCheck, "KLICCheck"))
	{
		KLICButton.SetVisibility(true);
		GeoPC.bKLIC = true;
	}

	CheckIsChecked(WaterwerkCheck, "WaterwerkCheck");
	CheckIsChecked(VCACheck, "VCACheck");
	CheckIsChecked(BRLCheck, "BRLCheck");
	CheckIsChecked(WerkbriefCheck, "WerkbriefCheck");
}


function bool InternalOnKeyEvent(out byte Key,out byte State,float delta)
{
	/// Swallow Escape key event
	if(bIgnoreEsc && Key == 0x1B)
		return true;

	return true;
}

function bool ButtonClick(GUIComponent Sender)
{
	if (Sender != None && AllowSelect)
	{
		switch(Sender)
	    {
			case MapButton:
				//
				Controller.OpenMenu("GeoInterface.MenuLevelMap");

				break;

			case KLICButton:
				//
				Controller.OpenMenu("GeoInterface.MenuKLICRapport");

				break;

	        case OpdrachtBonGoedButton:

				/// Already approved before? In that case it's the Close button
				if (GeoPC.playeractions.ApprovedAssignment)
				{
					Controller.CloseMenu(false);
					return true;
				}

				/// jln - 30-09-2008
				/// Check if we have actually gotten a reaction on ALL checkmarks:
				if (CheckApprovalState() == false)
				{
					/// Warn player:
					Controller.OpenMenu("GeoInterface.dialogAlert", IL8N("notenoughchecks") );
				}
				else
				{
					/// Okay, continue:
					/// jln - 25-09-2008 Set playercontroller value so that we know the opdracht has been seen:
					GeoPC.playeractions.ApprovedAssignment = true;
					Controller.CloseMenu(false);
				}

				break;
	    }
	}

	return true;
}

function bool CheckApprovalState()
{

	if (GeoApprovalCheckOpdracht.GetApprovalState() < 0) return false;
	if (GeoApprovalCheckAlgemeen.GetApprovalState() < 0) return false;
	if (GeoApprovalCheckVeiligheid.GetApprovalState() < 0) return false;
	if (GeoApprovalCheckVoorbereiding.GetApprovalState() < 0) return false;

	/// OTherwise, return true:
	return true;

}

function EnableClicked(string type, int istate)
{
	/// Scenario specific..
	if (type == "veiligheid" && istate == 1)
	{
		/// Enable click:
		KLICButton.SetVisibility(true);
		GeoPC.bKLIC = true;

		/// jln - 10-12-2008 SONDEER-208  - KLIC-melding not check
		KLICCheck.Image = Material'GeoGUIContent.Icons.checkbox_marked';

	}

	if (type == "algemeen")
	{
		/// Give player a map!
		GeoPC.GivePlayerMap();

		if(GeoPC.GetScenarioNumber() != 2)		
		{
			MapButton.SetVisibility(true);
		}

	}

}

function bool OnDraw(Canvas MyCanvas)
{
	local float x;
	local float y;

	Super.OnDraw(MyCanvas);

	return true;

	/// Draw line grid:
	/// To assist in button placement.
	for (y = 0; y <= 1.0; y = y + 0.1)
	{
		/// Horizontal line
		MyCanvas.SetPos(0, y * MyCanvas.SizeY);
		MyCanvas.DrawHorizontal( y * MyCanvas.SizeY, MyCanvas.SizeX );

		for (x = 0; x <= 1.0; x = x + 0.1)
		{
			/// Vertical line;
			MyCanvas.SetPos(x * MyCanvas.SizeX, 0);
			MyCanvas.DrawVertical( x * MyCanvas.SizeX, MyCanvas.SizeX )  ;


			/// Draw text:
			MyCanvas.SetPos((x * MyCanvas.SizeX) + 4, (y * MyCanvas.SizeY) + 10);
			MyCanvas.DrawText("x: " $ x);

			MyCanvas.SetPos((x * MyCanvas.SizeX) + 4, (y * MyCanvas.SizeY) + 18);
			MyCanvas.DrawText("y: " $ y);

		}


	}

	 return true;
}


//=============================================================================
// Date       Id   Modification
//=============================================================================
defaultproperties
{

	AllowSelect = true
	bAllowedAsLast=true
    bDisconnectOnOpen=false
    bIgnoreEsc=true
    bPersistent=false

	WinWidth=1.0
	WinHeight=1.0
	WinLeft=0.0
	WinTop=0.0


	Begin Object Class=GeoImage name=TPaperBackground
		WinWidth=0.45
		WinLeft=0.05
		WinTop=0.05
		WinHeight=0.9
		ImageStyle=ISTY_Scaled
		Image=Material'GeoGUIContent.Stretchable.paper'
	End Object

	Begin Object Class=GeoFrame name=TDialogBackground
		WinWidth=0.4
		WinLeft=0.55
		WinTop=0.25
		WinHeight=0.7
	End Object

    Begin Object class=GeoLabel Name=TOpdrachtbonLabel
		WinHeight=0.035
		WinLeft=0.1
		WinTop=0.1
		TextColor=(R=110,G=66,B=66,A=255)
		TextFont="GeoLargeFont"
	End Object

	Begin Object class=GeoLabel Name=TControleLijstLabel
		WinHeight=0.035
		WinLeft=0.65
		WinTop=0.12
		TextFont="GeoLargeFont"
	End Object

    Begin Object class=GeoLabel Name=TCategorieLabel
		WinHeight=0.025
        TextColor=(R=110,G=66,B=66,A=255)
	End Object

    Begin Object class=GeoLabel Name=TContentLabel
		WinHeight=0.017
		WinWidth=0.35
        TextColor=(R=0,G=0,B=0,A=255)
        TextFont="GeoSmallerFont"
	End Object

	Begin Object class=GeoImage Name=TCheckBox
		OnClick=ButtonClick
		Image=Material'GeoGUIContent.Icons.checkbox_unmarked'
		ImageStyle=ISTY_Scaled
		WinHeight=0.02
		WinWidth=0.02
		RenderWeight=1
	End Object

    Begin Object Class=GeoButtonSmall Name=TMapButton
		WinWidth=0.085
		OnClick=ButtonClick
    End Object

	Begin Object Class=GeoButtonSmall Name=TKLICButton
        WinWidth=0.123
		OnClick=ButtonClick
    End Object

	Begin Object class=GeoLabel name=TVoorbereidingLabel
		WinHeight=0.015
		WinWidth=0.3
        TextAlign=TXTA_Right
        TextColor=(R=0,G=0,B=0,A=255)
        TextFont="GeoSmallerFont"
	End Object

	Begin Object class=GeoLabel name=TJuistOnjuistLabel
		WinHeight=0.015
		WinWidth=0.1
		WinLeft=0.40
		WinTop=1.0
		TextFont="GeoSmallerFont"
        TextAlign=TXTA_Center
	End Object

	Begin Object class=GeoMultiLineLabelSmall name=TOpdrachtTextBox
		WinHeight=0.115
	End Object

	Begin Object class=GeoLabel name=TControleLabel
		WinHeight=0.03
		WinWidth=0.25
	End Object

	Begin Object class=GeoMultiLineLabel name=TUitlegTextBox
		WinHeight=0.155
	End Object

    Begin Object Class=GeoButton Name=TOpdrachtbonGoedButton
        OnClick=ButtonClick
        WinWidth=0.21
    End Object

	Begin Object class=GeoApprovalCheck name=TGeoApprovalOpdracht
		WinHeight=0.015
		WinWidth=0.04
		WinLeft=0.78
		WinTop=0.4
		sApprovalType="opdracht"
	End Object

	Begin Object class=GeoApprovalCheck name=TGeoApprovalAlgemeen
		WinHeight=0.015
		WinWidth=0.045
		WinLeft=0.78
		WinTop=0.48
		sApprovalType="algemeen"
	End Object


	Begin Object class=GeoApprovalCheck name=TGeoApprovalVeiligheid
		WinHeight=0.015
		WinWidth=0.04
		WinLeft=0.78
		WinTop=0.56
		sApprovalType="veiligheid"
	End Object

	Begin Object class=GeoApprovalCheck name=TGeoApprovalVoorbereiding
		WinHeight=0.015
		WinLeft=0.78
		WinTop=0.64
		sApprovalType="voorbereiding"
	End Object

	PaperBackground=TPaperBackground
	DialogBackground=TDialogBackground

	// opdrachtbon itself
	OpdrachtbonLabel=TOpdrachtBonLabel

    CategorieOpdrachtLabel=TCategorieLabel
	OpdrachtText=TOpdrachtTextBox

	CategorieAlgemeenLabel=TCategorieLabel
	TitelLabel=TContentLabel
	DatumLabel=TContentLabel
	LocatieLabel=TContentLabel
	OpdrachtgeverLabel=TContentLabel

	CategorieVeiligheidLabel=TCategorieLabel
	VerontreinigdeGrondLabel=TContentLabel
	VGPlanLabel=TContentLabel
	SpoorveiligheidLabel=TContentLabel
	VerkeersafzettingenLabel=TContentLabel
	WaterwerkLabel=TContentLabel
	KLICLabel=TContentLabel
	VCALabel=TContentLabel
	BRLLabel=TContentLabel
	WerkbriefLabel=TContentLabel
	VerontreinigdeGrondCheck=TCheckBox
	VGPlanCheck=TCheckBox
	SpoorveiligheidCheck=TCheckBox
	VerkeersafzettingenCheck=TCheckBox
	WaterwerkCheck=TCheckBox
	KLICCheck=TCheckBox
	VCACheck=TCheckBox
	BRLCheck=TCheckBox
	WerkbriefCheck=TCheckBox
	MapButton=TMapButton
	KLICButton=TKLICButton

	CategorieVoorbereidingLabel=TCategorieLabel
	ToestemmingLabel=TContentLabel
	UitzettenLabel=TContentLabel
	InmetenLabel=TContentLabel
	WaterpassenLabel=TContentLabel
	ToestemmingPartijLabel=TVoorbereidingLabel
	UitzettenPartijLabel=TVoorbereidingLabel
	InmetenPartijLabel=TVoorbereidingLabel
	WaterpassenPartijLabel=TVoorbereidingLabel

	ControleLijstLabel=TControleLijstLabel

	OpdrachtControleLabel=TControleLabel
	AlgemeenControleLabel=TControleLabel
	VeiligheidControleLabel=TControleLabel
	VoorbereidingControleLabel=TControleLabel

	JuistLabel=TJuistOnjuistLabel
	OnjuistLabel=TJuistOnjuistLabel

	UitlegText=TUitlegTextBox

	OpdrachtbonGoedButton=TOpdrachtbonGoedButton

   	GeoApprovalCheckOpdracht=TGeoApprovalOpdracht
	GeoApprovalCheckAlgemeen=TGeoApprovalAlgemeen
	GeoApprovalCheckVeiligheid=TGeoApprovalVeiligheid
	GeoApprovalCheckVoorbereiding=TGeoApprovalVoorbereiding

	VGapSmall=0.013
	VGapMedium=0.035
	VGapLarge=0.06
	HGap=0.012
	DialogGap=0.05

	OnKeyEvent=InternalOnKeyEvent
}